1 !
	500.10 - STAT11 - STAT11

		STAT11 ENTRY MODULE

	RELEASED FOR SUBMISSION TO THE DECUS LIBRARY BY THE DEC
	ENGINEERING SYSTEMS GROUP AND THE EDUCATION PRODUCTS GROUP
		SEPTEMBER, 1977


2 !	COPYRIGHT (C) 1973, DIGITAL EQUIPMENT CORPORATION,

			MAYNARD, MASSACHUSETTS

3 !	THIS SOFTWARE IS FURNISHED TO PURCHASER UNDER A LICENSE FOR USE
	ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH INCLUSION OF
	DEC'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH SYSTEM, EXCEPT AS
	MAY OTHERWISE BE PROVIDED IN WRITING BY DEC.

4 !	THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT
	NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL
	EQUIPMENT CORPORATION.

5 !	DEC ASSUMES NO RESPONSIBILITY FOR USE OR RELIABILITY OF ITS
	SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.



6 !	THIS IS THE ENTRY MODULE FOR THE STAT11 PACKAGE.



7 ! 	AUTHOR:		MICHAEL D. KNAUER

	VERSION NUMBER:	001

	DATE:		OCTOBER, 1973



8  !	MODIFICATIONS:  MAY, 1975

	MODIFIED TO ACCEPT MISSING DATA POINTS AND TO PASS THE ACCOUNT
	NUMBER WHERE THE PROGRAMS ARE STORED IN CORE COMMON

		BY ARDOTH HASSLER WILSON
		   CENTRAL STATE UNIVERSITY
		   EDMOND OKLAHOMA


00009!	MODIFICATIONS:  JUNE, 1976

	CTRL/C TRAP ADDED

10 !

	CALLING ARGUMENTS

11 !		NONE -- THIS IS THE FIRST MODULE EXECUTED IN THE STAT11
		PACKAGE -- HENCE NO ARGUMENTS ARE PASSED TO IT.



20 !	

	RETURNING ARGUMENTS


22 !		1) VARIABLE NAME:	F1$
		   RANGE OF VALUES:	ANY LEGAL BASIC-PLUS FILE NAME
		   USE:			THIS IS THE USER'S VIRTUAL MATRIX
					INPUT FILE, WHICH IS READ BY DATAIN
					AND STORED IN FILE F3$

23 !		2) VARIABLE NAME:	F2$
		   RANGE OF VALUES:	ANY LEGAL BASIC-PLUS FILE NAME
		   USE:			TO SAVE FOR THE USER THE DATA IN F3$

24 !		3) VARIABLE NAME:	F3$
		   RANGE OF VALUES:	S00000.RWM - S99999.RWM
		   USE:			THIS IS THE 250 ROW BY 15 COLUMN
					VIRTUAL MATRIX USED BY ALL STAT11
					MODULES

25 !		4) VARIABLE NAME:	A$
		   RANGE OF VALUES:	SIX LETTER CODE (PROGRAM NAME) FOR
					THE FIRST ANALYSIS TO BE PERFORMED
		   USE:			FOR CHAINING TO FIRST ANALYSIS AFTER
					INPUT FILE HAS BEEN READ AND EDITED

26 !



30 !	DESCRIPTION OF FUNCTION

		STAT11 IS THE ENTRY MODULE TO THE STAT11 PACKAGE.

31 !		IT ASKS THE USER FOR INPUT AND OUTPUT FILE NAMES, AND FOR THE
		FIRST ANALYSIS TO BE PERFORMED.

32 !		STAT11 OPENS AND CLOSES THE SPECIFIED FILES TO MAKE SURE
		THEY CAN BE USED, AND CHECKS THE ANALYSIS CODE TO VERIFY
		THAT IT IS A LEGAL OPTION.

33 !		STAT11 PASSES THE RETURNING ARGUMENTS VIA COMMON STORAGE
		AND TRANSFERS CONTROL (CHAINS) TO DATAIN AT ENTRY POINT
		LINE #35.

34 !		THIS MODULE IS EXECUTED ONLY ONCE EACH TIME THE STAT11
		PACKAGE IS RUN.

36 !






90 !

	THIS FILENAME INPUT ROUTINE OPENS AND CLOSES THE SPECIFIED FILES TO
	MAKE SURE THAT THEY EXIST AND THAT STAT11 CAN ACCESS THEM.



100	ON ERROR GOTO 710: GOSUB 10000: DIM G9(6%)
102	PRINT: PRINT "STAT11             ";TIME$(0%);"   ";DATE$(0%)
104  PRINT
110  PRINT "PLEASE ENTER NAMES OF INPUT AND OUTPUT FILES.(FORM";
115  PRINT ": IN,OUT)"
120  INPUT "(* FOR TERMINAL)";F1$,F2$
130  PRINT
134  IF F1$<>"*" THEN OPEN F1$ FOR INPUT AS FILE 1
136  CLOSE 1
140  IF F1$="*" THEN F1$="KB:"
142  IF F2$<>"*" THEN OPEN F2$ AS FILE 2 
144  CLOSE 2
150  IF F2$="*" THEN F2$="KB:"
155 !

	THE NEXT FEW LINES SET UP FILE NAMES IN CHARACTER STRINGS THAT WILL
	BE PASSED FROM MODULE TO MODULE VIA COMMON STORAGE.  F3$ IS THE
	VIRTUAL MATRIX THAT THE USER'S INPUT FILE IS READ INTO.
156 !	F3$ IS UNIQUELY NAMED USING THE TIME OF DAY SO THAT MULTIPLE USERS'
	FILES WILL NOT GET MIXED UP.


160  F3$="S"+LEFT(MID(NUM$(TIME(0)),2%,5%)+"00000",5%)+".RWM     "
170  F2$=LEFT(F2$+SPACE$(15%),15%)
180  F1$=LEFT(F1$+SPACE$(15%),15%)
183
	A9$="[1,5]"	! ACCOUNT WHERE ALL PROGRAMS ARE STORED

187	A9$=A9$+SPACE$(1%) UNTIL LEN(A9$)=9%
190	F$=F1$+F2$+F3$+"00000"+"00000"+"STATCM"+A9$
192 !	

	THE NEXT SECTION OF CODE ASKS THE USER FOR THE FIRST ANALYSIS,
	TAKES THE LEFT 6 CHARACTERS OF THAT CODE, REPLACES SPACES AND DASHES
	WITH ZEROES, AND CHECKS TO MAKE SURE IT IS A VALID STAT11 OPTION.


195  GOTO 410
200  PRINT "ENTER ANALYSIS TO BE PERFORMED."
210  INPUT LINE A1$ : PRINT
215  A1$=LEFT(A1$,LEN(A1$)-2)
220  A$=LEFT(A1$+"      ",6%)
230  IF A$="FINISH" GOTO 690
300  X=X                   ! SPECIAL MODULES CAN BE CKD FOR ABOVE
310  CHANGE A$ TO G9
320  FOR I%=1% TO 6%
330  IF G9(I%)=ASCII(" ") THEN G9(I%)=ASCII("0")
340  IF G9(I%)=ASCII("-") THEN G9(I%)=ASCII("0")
350  NEXT I%
360  CHANGE G9 TO A$
362  IF A$="EDIT00" GOTO 600
364  IF A$="TRANSF" GOTO600
366  IF A$="ELEMEN" GOTO 600
368  IF A$="CROSS0" GOTO 600
370  IF A$="CORREL" GOTO 600
372  IF A$="RANK0C" GOTO 600
374  IF A$="CHI0SQ" GOTO600
376  IF A$="T0TEST" GOTO600
377  IF A$="ANALYS" GOTO 600
378  IF A$="REGRES" GOTO 600
380  IF A$="STEPWI" GOTO 600
382  IF A$="SCATTE" GOTO 600
384  IF A$="HISTOG" GOTO 600
386  IF A$="LINE0P" GOTO 600
388  IF A$="HELP00" GOTO 430
390 !

	THE NEXT SECTION PRINTS A LIST OF THE VALID ANALYSIS OPTIONS WHEN THE
	USER TYPES IN 'HELP'.


400  PRINT "INVALID ANALYSIS CODE, PLEASE TRY AGAIN"
410  PRINT "TYPE 'HELP' FOR A LIST OF ANALYSIS CODES":PRINT
420  GOTO 200
430  PRINT "ANALYSIS CODE         ABBREVIATION"
440  PRINT
450  PRINT "EDIT                     EDIT"
460  PRINT "TRANSFORMATION           TRANSF"
470  PRINT "ELEMENTARY STATISTICS    ELEMEN"
480  PRINT "CROSS TABULATION         CROSS"
490  PRINT "CORRELATION              CORREL"
500  PRINT "RANK CORRELATION         RANK-C"
510  PRINT "CHI-SQUARED              CHI-SQ"
520  PRINT "T-TEST                   T-TEST"
525  PRINT "ANALYSIS OF VARIANCE     ANALYS"
530  PRINT "REGRESSION               REGRES"
540  PRINT "STEPWISE/MULTIPLE        STEPWI"
545  PRINT "     REGRESSION"
550  PRINT "SCATTER DIAGRAM          SCATTE"
560  PRINT "HISTOGRAM                HISTOG"
570  PRINT "LINE PLOT                LINE-P"
580  PRINT "FINISH                   FINISH"
590  PRINT
595  GOTO 200
598 !

	THE NEXT LINES COLLECT ALL THE CHARACTER STRINGS THAT ARE TO BE 
	PASSED TO THE NEXT MODULE, PLACES THEM IN COMMON, AND CHAINS TO DATAIN.


600  F$=F1$+F2$+F3$+"00000"+"00000"+A$+A9$+SPACE$(15%)
610  R$=SYS(CHR$(8)+F$)
620  CHAIN "DATAIN"+A9$ 35
680 !

	CONTROL IS TRANSFERRED HERE IF THE USER DECIDES TO QUIT BEFORE
	HE HAS STARTED.


690  PRINT "STAT11 TERMINATED  "; TIME$(0); "    "; DATE$(0)
700	GOTO 32750
705 !

	THIS IS AN ON ERROR ROUTINE IN CASE THE USER-SPECIFIED FILES OR 
	FILENAMES ARE GOOFED UP.


710	IF ERR=28% THEN GOSUB 10000: RESUME 690
715	IF ERL<140 THEN 717 ELSE IF ERL<146 THEN 800
	ELSE ON ERROR GOTO 0
717	PRINT "STAT11 IS UNABLE TO USE ";F1$;"  AS THE INPUT FILE"
720  PRINT "YOU SHOULD CHECK THE SPELLING OF THE FILE NAME"
725  PRINT "AND THE FILE'S PROTECTION CODE FOR STARTERS"
740  RESUME 104
800  PRINT "STAT11 IS UNABLE TO USE ";F2$;" AS THE OUTPUT FILE"
810  GOTO 720
10000	V0$=SYS(CHR$(6%)+CHR$(-7%)): RETURN	! CTRL/C TRAP
32750	END