1 !
	500.16 - STAT11 - ELEMEN

		ELEMENTARY STATISTICS MODULE

	RELEASED FOR SUBMISSION TO THE DECUS LIBRARY BY THE DEC
	ENGINEERING SYSTEMS GROUP AND THE EDUCATION PRODUCTS GROUP
		SEPTEMBER, 1977


2 !	COPYRIGHT (C) 1973, DIGITAL EQUIPMENT CORPORATION,

			MAYNARD, MASSACHUSETTS

3 !	THIS SOFTWARE IS FURNISHED TO PURCHASER UNDER A LICENSE FOR USE
	ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH INCLUSION OF
	DEC'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH SYSTEM, EXCEPT AS
	MAY OTHERWISE BE PROVIDED IN WRITING BY DEC.

4 !	THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT
	NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL
	EQUIPMENT CORPORATION.

5 !	DEC ASSUMES NO RESPONSIBILITY FOR USE OR RELIABILITY OF ITS
	SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.



6 !	THIS MODULE PRINTS A TABLE OF SEVERAL ELEMENTARY STATISTICS FOR
	EACH VARIABLE (COLUMN) IN THE DATA MATRIX.



7 ! 	AUTHOR:		MICHAEL D. KNAUER

	VERSION NUMBER:	001

	DATE:		OCTOBER, 1973



8  !	MODIFICATIONS:  MAY, 1975

	MODIFIED TO ACCEPT MISSING DATA POINTS
		BY ARDOTH HASSLER WILSON
		   CENTRAL STATE UNIVERSITY
		   EDMOND, OKLAHOMA


00009!	MODIFICATIONS:  JUNE, 1976

	CTRL/C TRAP ADDED

10 !

	CALLING ARGUMENTS

11 !		1) VARIABLE NAME:	F4$
		   RANGE OF VALUES:	S00000.ESF - S99999.ESF
		   USE:			THIS VIRTUAL MATRIX FILE CONTAINS
					THE ELEMENTARY STATISTICS THAT THIS
					MODULE PRINTS OUT.

13 !		2) VARIABLE NAME:	C%
		   RANGE OF VALUES:	1 - 15
		   USE:			CONTAINS THE NUMBER OF VARIABLES
					(ONE ROW FOR EACH VARIABLE) DESCRIBED
					IN THE ELEMENTARY STATISTICS FILE F4$

20 !


	RETURNING ARGUMENTS

22 !		NONE -- THIS MODULE DOES NOT ALTER OR ADD TO ANY OF THE
			FILES OR VARIABLES PASSED TO IT.




30 !	DESCRIPTION OF FUNCTION

		THIS MODULE PRINTS A TABLE OF SEVERAL ELEMENTARY STATISTICS
		FOR EACH VARIABLE (COLUMN) IN THE DATA MATRIX.

31 !		THESE STATISTICS ARE THE MAXIMUM VALUE, MINIMUM VALUE,
		MEAN, STANDARD DEVIATION, STANDARD ERROR, AND RANGE.

33 !		AFTER PRINTING THIS TABLE, ELEMEN TRANSFERS CONTROL TO
		THE STATCM MODULE.



48 !

	THE FIRST SECTION OF CODE RETRIEVES THE CALLING ARGUMENTS FROM
	COMMON STORAGE AND OPENS THE ELEMENTARY STATISTICS FILE (F4$).



50	ON ERROR GOTO 9000: GOSUB 10000: F$=SYS(CHR$(7%))
52   R%=VAL(MID(F$,46%,5%))
54   C%=VAL(MID(F$,51%,5%))
56   F3$=MID(F$,31%,15%)
58   F4$=LEFT(F3$,6%)+".ESF"
59	A9$=MID(F$,62%,9%): A9$=LEFT(A9$,INSTR(5%,A9$,"]"))
60   OPEN F4$ FOR INPUT AS FILE 4
70   DIM#4,S(10%,15%)
75 !


	THE FOLLOWING CODE PRINTS THE TABLE, ONE ROW FOR EACH VARIABLE.
	NOTE THAT COLUMN #2 OF THE FILE F4$ IS NOT PRINTED; IT CONTAINS 
	INTERMEDIATE VALUES THAT WERE USED TO COMPUTE THE MEANS AND 
	STANDARD DEVIATIONS.


80   PRINT : PRINT 
90  PRINT " VAR.    N    MAXIMUM    MINIMUM     MEAN    STD. DEV.";
100  PRINT " STD. ERROR    RANGE"
110  PRINT
120  FOR I%=1% TO C%
130 PRINT USING "  ##  ####",I%,S(0%,I%);
140  FOR J%=1% TO 7%
150  IF J%=3% GOTO 170
160  PRINT USING " #####.####",S(J%,I%);
170  NEXT J%
180  PRINT 
190  NEXT I%
195 !


	THE LAST SECTION CLOSES F4$, LOADS THE INFORMATION IT RETRIEVED
	FROM COMMON BACK INTO COMMON, AND TRANSFERS CONTROL TO STATCM.


200  CLOSE 4
210  PRINT : PRINT
220  R$=SYS(CHR$(8)+F$)
230  CHAIN "STATCM"+A9$
09000	IF ERR=28% THEN GOSUB 10000: RESUME 200
09010	ON ERROR GOTO 0
10000	V0$=SYS(CHR$(6%)+CHR$(-7%)): RETURN	! CTRL/C TRAP
32750	END